Gamers Delight 2/Gamers Delight 2.iso/Aminet/game/role/drink_drown.lha/Drink&Drown.AMOS/Drink&Drown.amosSourceCode

AMOS Source Code | 1994-03-12 | 46KB | 1,027 lines

Rem *** Drink & Drown
Rem *** Amiga version by Roland Acton, October 1991
Rem *** This program is public domain
Set Buffer 30
 Extension_5_003A
Dim SITUATION$(48),RESPONSE$(48,3),GOODCOMEBACK$(48,3),BADCOMEBACK$(48,3),GOODPOINTS(48,3),BADPOINTS(48,3),SPECIAL(48),TUNE(48),RANK$(17),NODRINK$(12),PHRASE$(11),NAME$(11)
Hide
Amos Lock
Amos To Front
SETUP
ENTERGAME: TITLEPAGE
Screen 0 : Screen Show 0 : Pen 1 : Paper 0 : Cls
If Right$(A$,1)=" " Then MUSMENU : Clear Key : Goto ENTERGAME
MEDINTERFACE[50]
If A$="advice" Then HELP=1 : ADVICE : Clear Key : Goto ENTERGAME
Auto View On : Palette 0,$FFF,$F,$F0,$F00,$FF0
Rem *** The original version of the game allowed the user to type in
Rem *** his age and weight, and used this to affect the drink limit.
Rem *** Since there was too much potential for abuse, I decided just
Rem *** to forget about it and determine the limit randomly.
Rem Input "What's your weight?";WEIGHT
Rem Print
Rem If WEIGHT<95 Then Print "You can't drink, you're a lightweight!" : Print
Rem If WEIGHT>200 Then Print "Go on a diet, pork-butt!"
Rem Input "What's your age?";AGE
Rem Print
Rem If AGE<18 Then Print "Minors beware!" : Print
Rem If AGE>30 Then Print "Find another hobby, you old lush!" : Print
WEIGHT=150 : AGE=25
Randomize Timer : Curs Off
LIMIT=Int((4*WEIGHT+12*AGE)/130)+Rnd(4) : If LIMIT>12 Then LIMIT=12
CASH#=10.0 : PUKES=0 : PASSOUT=0 : DIDHEDRINK=0 : U=0 : SCORE=100 : DRINK$="a" : LASTPHRASE=1 : LASTNAME=1 : PHRASE$(11)="Other" : NAME$(11)="other" : SECRETDRINK=Rnd(31)+1 : SUPERSWEAR=Rnd(20)+2
Rem *** These are cheat codes. They are not as helpful as they seem!
If A$="money" Then CASH#=50.0
If A$="score" Then SCORE=1000
If A$="limit" Then LIMIT=24
STATUSLINE
Locate 0,14 : Centre "Your drink limit tonight is"+Str$(LIMIT)+"."
FLIPSCREENS
WASTETIME
STATUSLINE
Locate 0,12
Print "Which bar will you begin at?"
Print
Print "Patrick's"
Print "Morgan's"
FLIPSCREENS
Show
Reset Zone
Set Zone 1,0,14*8 To 319,(15*8)-1
Set Zone 2,0,15*8 To 319,(16*8)-1
CHECKER: Repeat
   KEYPRESS=Mouse Click
Until KEYPRESS=1
KEYPRESS=Mouse Zone
If KEYPRESS<1 or KEYPRESS>2 Then Goto CHECKER
Print
If KEYPRESS=1
   Print "Enter Patrick's at your own risk!"
   EVENT=1
Else
   Print "Morgan's is a bad place!"
   EVENT=9
End If
SCENARIOS=8
FLIPSCREENS
WASTETIME
MAINLOOP: STATUSLINE
If LIMIT>0 Then S=1
If LIMIT=0 Then S=Rnd(4)+1
If DIDHEDRINK=1
   If S=0
      Locate 0,12 : Centre "That last drink made you puke! " : Pen 4 : Print "-75" : Pen 1
      PUKES=PUKES+1 : SCORE=SCORE-75 : FLIPSCREENS : MEDINTERFACE[20] : TWIDDLEFINGERS
   End If
   If S=-2 or S=-5 or S<-7
      Locate 0,12 : Centre "You're puking again! " : Pen 4 : Print "-100" : Pen 1
      PUKES=PUKES+1 : SCORE=SCORE-100 : FLIPSCREENS : MEDINTERFACE[20] : TWIDDLEFINGERS
   End If
End If
DIDHEDRINK=0
STATUSLINE
If PUKES>Rnd(2)+3 Then PASSOUT=1 : Goto FINISHGAME
DISPLAYPICTURE
GIVEEVENT
MEDINTERFACE[TUNE(EVENT)]
POLLRESPONSE
Locate 0,18
KARMA=Rnd(1)+1 : PLANNER=SPECIAL(EVENT)
BEGINIF: If PLANNER<=2
   If KARMA=1
      Print GOODCOMEBACK$(EVENT,RESPONSE)+" "; : Pen 3 : Memorize X : Memorize Y : Print GOODPOINTS(EVENT,RESPONSE) : Remember X : Remember Y : Print "+" : Pen 1 : SCORE=SCORE+GOODPOINTS(EVENT,RESPONSE) : MEDINTERFACE[17]
   End If
   If KARMA=2
      Print BADCOMEBACK$(EVENT,RESPONSE)+" "; : Pen 4 : Print BADPOINTS(EVENT,RESPONSE) : Pen 1 : SCORE=SCORE+BADPOINTS(EVENT,RESPONSE) : MEDINTERFACE[18]
   End If
End If
If PLANNER=3
   CASH#=CASH#-0.25 : PLANNER=0 : Goto BEGINIF
End If
If PLANNER=4
   If RESPONSE=2
      CASH#=CASH#-0.25
   Else
      CASH#=CASH#-0.5
   End If
   PLANNER=0 : Goto BEGINIF
End If
If PLANNER=5
   If RESPONSE=2
      CASH#=CASH#-1.0
   End If
   If(RESPONSE=3) and(KARMA=1)
      CASH#=CASH#-5.0
   End If
   PLANNER=0 : Goto BEGINIF
End If
If PLANNER=6
   If KARMA=1
      If RESPONSE=2
         CASH#=CASH#+1.0
      Else
         CASH#=CASH#+10.0
      End If
   End If
   PLANNER=0 : Goto BEGINIF
End If
If PLANNER=7
   If RESPONSE=1
      CASH#=CASH#-1.0
   End If
   If(RESPONSE=3) and(KARMA=1)
      CASH#=CASH#-0.35
   End If
   PLANNER=0 : Goto BEGINIF
End If
If PLANNER=8
   KARMA=Rnd(2)
   If KARMA<2
      KARMA=1 : PLANNER=0 : Goto BEGINIF
   End If
   If RESPONSE=1
      PLANNER=0 : Goto BEGINIF
   End If
   Print BADCOMEBACK$(EVENT,RESPONSE)+" "; : Pen 3 : Memorize X : Memorize Y : Print BADPOINTS(EVENT,RESPONSE) : Remember X : Remember Y : Print "+" : Pen 1 : SCORE=SCORE+BADPOINTS(EVENT,RESPONSE) : MEDINTERFACE[17]
End If
If PLANNER=9
   KARMA=Rnd(2)
   If KARMA<2
      KARMA=1
   End If
   PLANNER=0 : Goto BEGINIF
End If
If PLANNER=10
   If(RESPONSE=1) and(KARMA=1)
      CASH#=CASH#-0.25
   End If
   PLANNER=0 : Goto BEGINIF
End If
If CASH#<0.0 Then CASH#=0.0
FLIPSCREENS
TWIDDLEFINGERS
BESTSCORE
STATUSLINE
Rem *** Swearing is fun, but not worthwhile.
Locate 0,12 : Centre "Do you want to swear?"
Ink 3 : Bar 13*8,15*8 To(18*8)-1,(18*8)-1 : Ink 4 : Bar 23*8,15*8 To(27*8)-1,(18*8)-1
Locate 14,16 : Paper 3 : Print "YES" : Locate 24,16 : Paper 4 : Print "NO" : Paper 0
FLIPSCREENS
Reset Zone
Set Zone 1,13*8,15*8 To(18*8)-1,(18*8)-1
Set Zone 2,23*8,15*8 To(27*8)-1,(18*8)-1
CK9: Repeat
   KEYPRESS=Mouse Click
Until KEYPRESS=1
KEYPRESS=Mouse Zone
If KEYPRESS<1 or KEYPRESS>2
   Goto CK9
End If
If KEYPRESS=1
   SWEARPRINTER: Reset Zone
   Cls : Centre "SWEAR LIST" : Print : Print
   Pen 2 : Centre "Choose a phrase and name from the lists" : Print : Centre "and click in the swear box." : Print : Print
   Pen 1 : Centre "PHRASES" : Print : Pen 5
   For C=1 To 9 Step 2 : A$=Zone$(PHRASE$(C),C) : Print "     "+A$; : Locate 25, : A$=Zone$(PHRASE$(C+1),C+1) : Print A$ : Next
   A$=Zone$(PHRASE$(11),11) : Print "     "+A$ : Print
   Pen 1 : Centre "NAMES" : Print : Pen 5
   For C=1 To 9 Step 2 : A$=Zone$(NAME$(C),C+11) : Print "     "+A$; : Locate 25, : A$=Zone$(NAME$(C+1),C+12) : Print A$ : Next
   A$=Zone$(NAME$(11),22) : Print "     "+A$ : Print : Print
   Ink 5 : Bar 1*8,21*8 To(38*8)-1,(24*8)-1
   Pen 4 : Paper 5 : A$=" "+PHRASE$(LASTPHRASE)+NAME$(LASTNAME)+" " : Centre A$ : Pen 1 : Paper 0
   Set Zone 23,1*8,21*8 To(38*8)-1,(24*8)-1
   FLIPSCREENS
   Screen Show 0 : Screen Hide 1
   CK5: Repeat
      KEYPRESS=Mouse Click
   Until KEYPRESS=1
   KEYPRESS=Mouse Zone
   If KEYPRESS<1 or KEYPRESS>23
      Goto CK5
   End If
   If KEYPRESS<12
      LASTPHRASE=KEYPRESS
   End If
   If KEYPRESS>11 and KEYPRESS<23
      LASTNAME=KEYPRESS-11
   End If
   Rem *** Interesting AMOS bug: if you select "other", the swear box
   Rem *** is supposed to update and display what you just typed in.
   Rem *** Interpreted, at least with Creator, it does. Compiled, it
   Rem *** doesn't!
   If(KEYPRESS=11) and(PHRASE$(11)="Other")
      Screen Copy Physic To 1 : Screen 1 : Screen Show 1 : Screen Hide 0
      Clear Key : Locate 5,11 : Cline : Input "";PHRASE$(11) : PHRASE$(11)=Left$(PHRASE$(11),14)+" "
      If PHRASE$(11)=" "
         PHRASE$(11)="Other" : LASTPHRASE=1
      End If
      Curs Off : Screen 0
   End If
   If(KEYPRESS=22) and(NAME$(11)="other")
      Screen Copy Physic To 1 : Screen 1 : Screen Show 1 : Screen Hide 0
      Clear Key : Locate 5,19 : Cline : Input "";NAME$(11) : NAME$(11)=Left$(NAME$(11),15)
      If NAME$(11)=""
         NAME$(11)="other" : LASTNAME=1
      End If
      Curs Off : Screen 0
   End If
   If KEYPRESS<23
      Goto SWEARPRINTER
   End If
   Locate 0,21 : Cline : Print : Cline : Print : Cline : Locate 0,22
   If SUPERSWEAR=LASTPHRASE+LASTNAME
      Centre "You said the SUPER SWEAR!"+Pen$(3)+" +100" : Pen 1
      SUPERSWEAR=Rnd(20)+2 : SCORE=SCORE+100 : MEDINTERFACE[14]
   Else
      Centre "You call that swearing?"+Pen$(4)+" -10" : Pen 1
      SCORE=SCORE-10 : MEDINTERFACE[16]
   End If
   FLIPSCREENS
   TWIDDLEFINGERS
End If
BESTSCORE
STATUSLINE
Locate 0,12
If CASH#<0.5
   If ENOUGH=0
      Ink 4 : Bar 5*8,13*8 To(34*8)-1,(17*8)-1
      Paper 4 : Locate 0,14 : Centre "You don't have enough money" : Print
      Centre "to buy a drink." : Paper 0
      ENOUGH=1
      Goto EXAMINEEND
   End If
   Goto DIDNOTEXPLAIN
End If
ENOUGH=0
Centre "How about "+DRINK$+" drink?"
Ink 3 : Bar 13*8,15*8 To(18*8)-1,(18*8)-1 : Ink 4 : Bar 23*8,15*8 To(27*8)-1,(18*8)-1
Locate 14,16 : Paper 3 : Print "YES" : Locate 24,16 : Paper 4 : Print "NO" : Paper 0
Locate 0,20 : Pen 4 : If LIMIT=0 Then Centre "WARNING: You're at your limit!"
If LIMIT<0 Then Centre "WARNING: Drink limit passed!"
Locate 0,22 : Pen 1
FLIPSCREENS
Reset Zone
Set Zone 1,13*8,15*8 To(18*8)-1,(18*8)-1
Set Zone 2,23*8,15*8 To(27*8)-1,(18*8)-1
Repeat
Until Mouse Key=0
CK2: Repeat
   KEYPRESS=Mouse Click
Until KEYPRESS=1
KEYPRESS=Mouse Zone
If KEYPRESS<1 or KEYPRESS>2
   Goto CK2
End If
If KEYPRESS=1
   DRINK$="another" : CASH#=CASH#-((5.0*(Rnd(14)+10.0))/100.0) : LIMIT=LIMIT-1 : S=S-1 : DIDHEDRINK=1
   If CASH#<0
      CASH#=0
   End If
   Cls : Centre "Drink Menu" : Print : Print : Reset Zone : Pen 2
   A$=Zone$("Alabama Slammer",1) : Print "     "+A$; : A$=Zone$("Tom Collins",2) : Locate 25, : Print A$
   A$=Zone$("Tequila Sunrise",3) : Print "     "+A$; : A$=Zone$("Pina Colada",4) : Locate 25, : Print A$
   A$=Zone$("Straw. Daquiri",5) : Print "     "+A$; : A$=Zone$("Gin & Tonic",6) : Locate 25, : Print A$
   A$=Zone$("Banana Daquiri",7) : Print "     "+A$; : A$=Zone$("Bloody Mary",8) : Locate 25, : Print A$
   A$=Zone$("H. Wallbanger",9) : Print "     "+A$; : A$=Zone$("Firecracker",10) : Locate 25, : Print A$
   A$=Zone$("V.O. & Ginger",11) : Print "     "+A$; : A$=Zone$("Jelly Bean",12) : Locate 25, : Print A$
   A$=Zone$("Vodka Martini",13) : Print "     "+A$; : A$=Zone$("Rum & Coke",14) : Locate 25, : Print A$
   A$=Zone$("Scotch & Soda",15) : Print "     "+A$; : A$=Zone$("Seven & 7",16) : Locate 25, : Print A$
   A$=Zone$("White Russian",17) : Print "     "+A$; : A$=Zone$("Vodka & 7",18) : Locate 25, : Print A$
   A$=Zone$("Black Russian",19) : Print "     "+A$; : A$=Zone$("Manhattan",20) : Locate 25, : Print A$
   A$=Zone$("Sloe Gin Fizz",21) : Print "     "+A$; : A$=Zone$("Kamikaze",22) : Locate 25, : Print A$
   A$=Zone$("Vodka Gimlet",23) : Print "     "+A$; : A$=Zone$("Stinger",24) : Locate 25, : Print A$
   A$=Zone$("Gin & Squirt",25) : Print "     "+A$; : A$=Zone$("Icepick",26) : Locate 25, : Print A$
   A$=Zone$("Tootsie Roll",27) : Print "     "+A$; : A$=Zone$("Zombie",28) : Locate 25, : Print A$
   A$=Zone$("Whiskey Sour",29) : Print "     "+A$; : A$=Zone$("Beer (any)",30) : Locate 25, : Print A$
   A$=Zone$("Boilermaker",31) : Print "     "+A$; : A$=Zone$("Screwdriver",32) : Locate 25, : Print A$
   Pen 1
   FLIPSCREENS
   MTL: Repeat
      KEYPRESS=Mouse Click
   Until KEYPRESS=1
   KEYPRESS=Mouse Zone
   If KEYPRESS<1 or KEYPRESS>32
      Goto MTL
   End If
   If KEYPRESS=SECRETDRINK
      SECRETDRINK=Rnd(31)+1 : SCORE=SCORE+100 : Locate ,20 : Centre "That's the SECRET SPECIAL! "+Pen$(3)+"+100" : Pen 1 : SUPSEC=1
   End If
   KEYPRESS=(40-5*LIMIT)+(5*Rnd(7))-(5*PUKES)
   If KEYPRESS<10
      KEYPRESS=10
   End If
   SCORE=SCORE+KEYPRESS
   Locate ,22 : Centre "Drink rating was"+Pen$(3)+Str$(KEYPRESS)+Pen$(1)+"."
   If SUPSEC=0
      MEDINTERFACE[15]
   Else
      MEDINTERFACE[14] : SUPSEC=0
   End If
Else
   RX=(5*LIMIT)-(5*Rnd(20))
   If RX>-10
      RX=-10
   End If
   U=U+1 : U=Min(U,12) : Centre NODRINK$(U)+" "+Pen$(4)+Str$(RX) : Pen 1 : SCORE=SCORE+RX : MEDINTERFACE[18]
   If U<6 and S<0
      S=2
   End If
   If U<4 and S<0
      S=3
   End If
End If
BESTSCORE
EXAMINEEND: FLIPSCREENS : TWIDDLEFINGERS
DIDNOTEXPLAIN: EVENT=EVENT+1 : SCENARIOS=SCENARIOS-1 : If SCENARIOS>0 Then Goto MAINLOOP
If EVENT>33 Then Goto FINISHGAME
SCENARIOS=8 : DRINK$="a" : STATUSLINE : Locate ,11 : Pen 4 : Centre ">>> WARNING <<<" : Locate ,13
MEDINTERFACE[50]
If EVENT=<17
   Centre "BE CAREFUL GOING TO ANOTHER BAR!" : Pen 1
   Locate 0,16 : Print "Which bar will you visit next?" : Print
   Print "Whiskey 1"
   Print "Mulligan's"
   FLIPSCREENS
   Reset Zone
   Set Zone 1,0,18*8 To 319,(19*8)-1
   Set Zone 2,0,19*8 To 319,(20*8)-1
   XT: Repeat
      KEYPRESS=Mouse Click
   Until KEYPRESS=1
   KEYPRESS=Mouse Zone
   If KEYPRESS<1 or KEYPRESS>2
      Goto XT
   End If
   If KEYPRESS=1
      EVENT=17
   Else
      EVENT=25
   End If
   For C=16 To 19 : Locate ,C : Cline : Next
   Locate 0,16 : Print "And how will you get there?" : Print
   Print "Walk"
   Print "Drive"
   FLIPSCREENS
   Reset Zone
   Set Zone 1,0,18*8 To 319,(19*8)-1
   Set Zone 2,0,19*8 To 319,(20*8)-1
   Repeat
   Until Mouse Key=0
   XV: Repeat
      KEYPRESS=Mouse Click
   Until KEYPRESS=1
   KEYPRESS=Mouse Zone
   If KEYPRESS<1 or KEYPRESS>2
      Goto XV
   End If
   C=Rnd(4)
   If KEYPRESS=1
      If C<2
         Print : Print "You got beat up by a gang. "; : Pen 4 : Print "-150" : Pen 1
         SCORE=SCORE-150 : MEDINTERFACE[18] : FLIPSCREENS : TWIDDLEFINGERS
      End If
   Else
      If C=0
         Print : Print "You find $20 on the car floor. "; : Pen 3 : Print "+125" : Pen 1
         SCORE=SCORE+125 : CASH#=CASH#+20.0 : MEDINTERFACE[5] : FLIPSCREENS : TWIDDLEFINGERS
      End If
      If C=1
         Print : Print "You just got nailed for DWI. "; : Pen 4 : Print "-250" : Pen 1
         SCORE=SCORE-250 : MEDINTERFACE[19] : FLIPSCREENS : TWIDDLEFINGERS
      End If
   End If
Else
   Centre "PUKE TOO MUCH AND YOU'LL PASS OUT!" : Pen 1
   Locate 0,16 : Print "Which exit will you leave this bar by?" : Print
   Print "Front door"
   Print "Side door"
   Print "Back door"
   FLIPSCREENS
   Reset Zone
   Set Zone 1,0,18*8 To 319,(19*8)-1
   Set Zone 2,0,19*8 To 319,(20*8)-1
   Set Zone 3,0,20*8 To 319,(21*8)-1
   XJ: Repeat
      KEYPRESS=Mouse Click
   Until KEYPRESS=1
   KEYPRESS=Mouse Zone
   If KEYPRESS<1 or KEYPRESS>3
      Goto XJ
   End If
   C=Rnd(3)
   If KEYPRESS=1
      If C=0
         Print : Print "You find $5 on the sidewalk. "; : Pen 3 : Print "+75" : Pen 1
         SCORE=SCORE+75 : CASH#=CASH#+5.0 : MEDINTERFACE[5] : FLIPSCREENS : TWIDDLEFINGERS : MEDINTERFACE[50]
      End If
   Else
      If KEYPRESS=2
         If C=0
            Print : Print "You get a second wind. Drink limit "; : Pen 3 : Print "+2"; : Pen 1 : Print "." : LIMIT=LIMIT+2
            If LIMIT<2
               LIMIT=2
            End If
            MEDINTERFACE[14] : FLIPSCREENS : TWIDDLEFINGERS : MEDINTERFACE[50]
         End If
         If C=1
            Print : Print "You witness a Mafia drug deal. "; : Pen 4 : Print "-175" : Pen 1
            SCORE=SCORE-175 : MEDINTERFACE[18] : FLIPSCREENS : TWIDDLEFINGERS : MEDINTERFACE[50]
         End If
      Else
         If C=0
            Print : Print "A mugger steals all your money. "; : Pen 4 : Print "-125" : Pen 1
            SCORE=SCORE-125 : CASH#=0.0 : MEDINTERFACE[18] : FLIPSCREENS : TWIDDLEFINGERS : MEDINTERFACE[50]
         End If
         If C=1
            Print : Print "You get raped by teenage girls. "; : Pen 3 : Print "+200" : Pen 1
            SCORE=SCORE+200 : MEDINTERFACE[17] : FLIPSCREENS : TWIDDLEFINGERS : MEDINTERFACE[50]
         End If
      End If
   End If
   For C=16 To 22 : Locate ,C : Cline : Next
   Locate 0,16 : Print "Okay, you made it outside. Pick a bar:" : Print
   Print "Bayview"
   Print "Rusty Nail"
   FLIPSCREENS
   Reset Zone
   Set Zone 1,0,18*8 To 319,(19*8)-1
   Set Zone 2,0,19*8 To 319,(20*8)-1
   Repeat
   Until Mouse Key=0
   XZ: Repeat
      KEYPRESS=Mouse Click
   Until KEYPRESS=1
   KEYPRESS=Mouse Zone
   If KEYPRESS<1 or KEYPRESS>2
      Goto XZ
   End If
   If KEYPRESS=1
      EVENT=33 : Print : Print "On to the Bayview!"
   Else
      EVENT=41 : Print : Print "Off to the Rusty Nail!"
   End If
   FLIPSCREENS
   WASTETIME
End If
BESTSCORE
Goto MAINLOOP
FINISHGAME: STATUSLINE : Locate 0,12
If PASSOUT=0
   Centre "You've completed your adventure through" : Print
   Centre "the last of three bars." : Print : Print
   Pen 3 : Centre "CONGRATULATIONS!" : Pen 1 : MEDINTERFACE[14]
Else
   Centre "You just passed out! Good night!" : MEDINTERFACE[18]
End If
Hide
FLIPSCREENS
TWIDDLEFINGERS
RANKINGS
If HELP=0
   HELP=1 : Cls : Locate 0,12 : Paper 2
   Ink 2 : Bar(1*8),(11*8) To(39*8)-1,(16*8)-1
   Centre "If you're having trouble, try typing" : Print
   Centre Chr$(34)+"advice"+Chr$(34)+" on the title screen before" : Print
   Centre "starting the game!" : Paper 0
   FLIPSCREENS
   WASTETIME
   WASTETIME
End If
Goto ENTERGAME
Procedure SETUP
   Shared MEDLOCATION,MEDMOD
   Close Workbench
   A$="Songplayer.o"+Chr$(0) : Dreg(1)=Varptr(A$)
   MEDLOCATION=Doscall(-150) : MEDLOCATION=(MEDLOCATION*4)+4
   A$="Loadmod.o"+Chr$(0) : Dreg(1)=Varptr(A$)
   LM=Doscall(-150) : LM=LM*4
   A$="Music"+Chr$(0) : Areg(0)=Varptr(A$)
   Call LM : MEDMOD=Dreg(0)
   Areg(0)=MEDMOD : Call MEDLOCATION+12
   Auto View Off
   CREDITS
   Screen Open 0,320,200,32,Lowres : Double Buffer : Reserve Zone 51 : Flash Off : Curs Off : Screen Hide
   Autoback 0 : Bob Update Off
   Screen Open 1,320,200,32,Lowres : Flash Off : Screen Hide
   Palette $0,$FFF,$F,$F0,$F00,$FF0 : Pen 5 : Paper 0 : Curs Pen 1 : Cls
   Reserve Zone 51
   Shared SITUATION$(),RESPONSE$(),GOODCOMEBACK$(),BADCOMEBACK$(),GOODPOINTS(),BADPOINTS(),SPECIAL(),TUNE(),RANK$(),NODRINK$(),PHRASE$(),NAME$()
   For C=1 To 48 : Read SITUATION$(C),SPECIAL(C),TUNE(C)
      For T=1 To 3 : Read RESPONSE$(C,T) : Next
      For T=1 To 3 : Read GOODCOMEBACK$(C,T) : Read GOODPOINTS(C,T) : Read BADCOMEBACK$(C,T) : Read BADPOINTS(C,T) : Next
   Next
   For C=1 To 17 : Read RANK$(C) : Next
   For C=1 To 12 : Read NODRINK$(C) : Next
   For C=1 To 10 : Read PHRASE$(C) : Next
   For C=1 To 10 : Read NAME$(C) : Next
   Data "You spot an empty bar stool.",0,1
   Data "Ease on over to it","Scramble and jump up on it","Pass it up"
   Data "You got it! You got it!",20,"Another guy gets there first.",-20
   Data "Ain't nobody gonna mess with you.",35,"It has a broken spring, ouch.",-35
   Data "Only lushes use stools.",35,"Too bad, it was a good seat.",-35
   Data "Your hair is messed up.",0,2
   Data "Run your hand through it","Shake your head","Whip out your comb"
   Data "It drives the girls crazy.",45,"Hair pulls out, you're going bald.",-45
   Data "Who needs a comb, anyway?",35,"Snot flies out of your nose.",-45
   Data "No hairballs in it.",30,"It's full of lint and dandruff.",-25
   Data "A waitress just brought you a drink.",5,3
   Data "Tip her nothing","Give her a buck","Stuff a five in her bra"
   Data "What did she ever do for you?",25,"That's what she thinks of you.",-50
   Data "She pinches your butt.",50,"A dollar won't get you laid.",-25
   Data "Says she'd rather get 10 later.",75,"She hands it back to you.",-75
   Data "A girl asks you to dance with her friend.",0,4
   Data "Say yes","Say no","Laugh in her face"
   Data "Looks like Christie Brinkley!",65,"Have a dance with Superhag.",-65
   Data "She was a hogger anyway.",35,"You turned down a blonde beauty.",-50
   Data "Her friend was another guy.",55,"She spits in your face.",-55
   Data "There's $10 on the floor.",6,5
   Data "Put your foot over it","Dive on it","Pick it up and pocket it"
   Data "It's all yours.",60,"There's dog-doo on your shoe.",-35
   Data "Good move - but it's only a $1.",25,"You miss and it blows away.",-40
   Data "A girl puts her hand in after it.",50,"The guy who lost it sees you.",-60
   Data "You see a girl you want.",0,1
   Data "Offer to buy her a drink","Strike a macho pose","Play "+Chr$(34)+"hard to get"+Chr$(34)
   Data "She falls for it.",55,"She laughs and says no thanks.",-55
   Data "You're turning her on.",55,"Your fly is open.",-55
   Data "She's burning for your body.",60,"You're also "+Chr$(34)+"hard to want."+Chr$(34),-60
   Data "A cute girl asks what time it is.",0,3
   Data "Look at your wrist and tell her","Say "+Chr$(34)+"Time to have sex with me"+Chr$(34),"Say "+Chr$(34)+"Ok, I'm game! What time is it?"+Chr$(34)
   Data "She admires your watch.",40,"You're not wearing a watch, fool.",-40
   Data "She says "+Chr$(34)+"I think you're right!"+Chr$(34),70,"She says "+Chr$(34)+"It's not THAT late."+Chr$(34),-70
   Data "Your wit captivates her.",45,"She asks somebody else.",-45
   Data "A girl falls down in front of you.",0,6
   Data "Laugh heartily","Help her up","Spit on her"
   Data "Why not? It was funny.",25,"She bites you on the ankle.",-60
   Data "Her pretty friend thanks you.",60,"She thinks you tripped her.",-45
   Data "The crowd cheers you on.",40,"Bad move, she's a lady wrestler.",-65
   Data "You want to start a conversation.",1,2
   Data Chr$(34)+"How about this crazy weather?"+Chr$(34),Chr$(34)+"Yep, that's the way it goes"+Chr$(34),Chr$(34)+"This is quite a bar, but not really"+Chr$(34)
   Data "You're a smalltalk expert.",40,"That opening line stinks.",-40
   Data "That's the way it's going, alright.",20,"Ya know, they've heard that.",-20
   Data "That was quite a put-down.",30,"You're quite a guy, but not really.",-30
   Data "Someone asks if you know a good joke.",0,7
   Data "Tell a dirty joke","Tell a clean joke","Say you don't know any"
   Data "It's disgusting and amusing.",25,"Everyone's repulsed.",-25
   Data "Strangely enough, it's funny.",30,"Clean jokes are no good.",-30
   Data "A good man knows his limitations.",40,"You're the biggest joke of all.",-40
   Data "You're hit in the back with an ice cube.",0,8
   Data "Ignore it","Peer over your shoulder","Turn around"
   Data "Right, don't let it bother you.",40,"It was really some skrock.",-55
   Data "A lovely girl wants your attention.",50,"You look like you're afraid.",-25
   Data "A foxy girl wants to talk.",50,"You're hit in the face with a beer.",-65
   Data "A female puts her hands over your eyes.",0,4
   Data "Say "+Chr$(34)+"I'm going blind! Ha Ha"+Chr$(34),"Take her hand and lick it","Grab her by the wrists"
   Data "She thinks she surprised you.",45,"You wish you were when you see her.",-60
   Data "She licks you back.",50,"She thinks you're gross.",-50
   Data "She loves forceful men.",45,"She hates physical abuse.",-40
   Data "An ugly girl asks what your name is.",0,1
   Data "Give her your friend's name","Tell her your real name","Say "+Chr$(34)+"Jack Meoff. Why?"+Chr$(34)
   Data "What are friends for?",25,"She knows you're lying.",-25
   Data "Her pretty friend wants to know.",40,"The police are looking for you.",-65
   Data "Always play it safe.",30,"She knees you in the groin.",-50
   Data "You spot an old girlfriend.",0,9
   Data "Give her a disgusted look","Go talk to her","Throw a table at her"
   Data "She regrets ever losing you.",40,"She never noticed you.",-40
   Data "She'll pay up the $50 she owes you.",65,"She blames you for her pregnancy.",-65
   Data "She won't ever bother you again.",40,"The tables are bolted to the floor.",-35
   Data "You see a girl carrying a cat.",0,6
   Data "Go pet it (the cat)","Yell "+Chr$(34)+"Look! Pure pussy!"+Chr$(34),"Set her up with your friend."
   Data "She loves animal lovers.",50,"Your hand gets bitten (by the girl).",-50
   Data "One hell of a line.",35,"She throws the cat at you.",-35
   Data "A great dirty trick.",45,"Her dad's a millionaire, dope.",-45
   Data "You have to take a piss bad.",0,7
   Data "Get in line for the john","Run past the people in line","Go in the corner, hope no one notices"
   Data "Your patience is appreciated.",35,"You can't wait and have an accident.",-60
   Data "When ya gotta go, ya gotta go.",40,"Oops, wrong john.",-40
   Data "All the girls get turned on.",70,"Everyone notices.",-70
   Data "The bouncer laughs and asks for some ID.",0,9
   Data "Laugh and say you don't have any","Show him some","Smile and walk on by"
   Data "He was just kidding.",20,"He gets mean and hassles you for it.",-20
   Data "He hardly glances at it.",35,"How degrading.",-35
   Data "Don't worry, you're a regular.",45,"He grabs you and demands some.",-45
   Data "Nothing much is going on right now.",0,10
   Data "Say "+Chr$(34)+"Oh yes oh yes oh yes...oh nooo"+Chr$(34),"Yell "+Chr$(34)+"Hey! Any girls wanna fuck me?"+Chr$(34),"Scream "+Chr$(34)+"How about those hard-ons!"+Chr$(34)
   Data "You're a ramblin' kinda guy.",35,"People think you're strange.",-35
   Data "Some of them do.",55,"There's no takers.",-55
   Data "What about them?",15,"You aren't improving things.",-15
   Data "Try snacking on some...",2,1
   Data "Pretzels","Peanuts","Potato chips"
   Data "Pretzels go well with alcohol.",25,"They're stale.",-25
   Data "Peanuts won't hurt to puke up.",25,"Yuck, somebody barfed on them.",-30
   Data "Low salt, good for blood pressure.",20,"There's no dip, except for you.",-15
   Data "Your favorite song is on the radio.",0,11
   Data "Ask a girl to dance to it","Howl and get rowdy","Play your "+Chr$(34)+"air guitar"+Chr$(34)+" to it"
   Data "She thinks you're charming.",45,"It's her least favorite.",-45
   Data "Yep, it's starting to gel.",35,"You appear to be drunk.",-35
   Data "A talent scout wants to hire you.",30,"You look like an air HEAD.",-30
   Data "The waitress winks at you.",0,3
   Data "Say "+Chr$(34)+"Is there something in your eye?"+Chr$(34),"Wink back","Whisper "+Chr$(34)+"The coat room in 5 minutes"+Chr$(34)
   Data "She says "+Chr$(34)+"Yeah - you."+Chr$(34),55,"Not any more.",-45
   Data "Check your supply of condoms, pal.",55,"It was just dirt in her eye.",-30
   Data "She says "+Chr$(34)+"Make it 2 minutes."+Chr$(34),60,"Ok, if you don't mind herpes.",-60
   Data "Test your skill on a video game...",3,12
   Data "Sentupeed","Pahk-Mann","Zaksonn"
   Data "3-D's bad enough when you're sober.",20,"Real good choice, maggot.",-20
   Data "A crowd of girls gathers to watch.",45,"This game is archaic.",-35
   Data "You set the new high score.",40,"The machine steals your quarter.",-30
   Data "You stagger into the girls' john.",10,2
   Data "Buy a tampon and smoke it","Pass out the tampons as party favors","Piss on every toilet seat"
   Data "The deodorant gets you high.",40,"The machine is empty.",-40
   Data "You're the life of the party.",35,"Pull the string - nothing happens.",-35
   Data "It's funny if you're not a girl.",25,"You're a no-class guy.",-25
   Data "A guy calls you a faggot.",0,7
   Data "Ask what he's doing later","Say "+Chr$(34)+"Go play with yourself!"+Chr$(34),"Call him a lesbian"
   Data "That line left him speechless.",35,"He's beating you up later.",-60
   Data "He backs down.",60,"The joke doesn't go over.",-35
   Data "An incredible comeback.",55,"Now he's really ticked off.",-55
   Data "A bright light is above you.",0,4
   Data "Squint","Say "+Chr$(34)+"This light here sucks"+Chr$(34),"Move out of the light"
   Data "Squinting makes you look manly.",30,"Your eyesight is going.",-30
   Data "Why not? It does suck.",20,"Then don't stand near it, dunce.",-20
   Data "You can make quick decisions.",35,"Don't let a light push you around.",-35
   Data "The bottom of your drink is wet.",0,1
   Data "Wipe it off with your hand","Use a napkin","Use your sleeve"
   Data "Now wipe it on your friend.",20,"Now where do you wipe your hand?",-20
   Data "Keep things tidy.",15,"Use a feminine napkin, too.",-15
   Data "You're very resourceful.",25,"It looks like snot-stains.",-25
   Data "You want to talk to a girl.",1,2
   Data Chr$(34)+"How about that Mideast crisis?"+Chr$(34),Chr$(34)+"What's a nice girl like you doing...",Chr$(34)+"Some crazy weather we've had lately"+Chr$(34)
   Data "The Mideast turns her on.",50,"The Mideast depresses her.",-30
   Data "...talking to a great guy like me?"+Chr$(34),40,"...talking to a jerk like me?"+Chr$(34),-40
   Data "She agrees and says "+Chr$(34)+"It's crazy."+Chr$(34),30,"Her family was killed in a tornado.",-50
   Data "A waitress brought the drink.",7,3
   Data "Tip her a dollar","Pat her on the head","Say "+Chr$(34)+"Keep the change"+Chr$(34)
   Data "Good for you.",30,"She doesn't even say thank you.",-30
   Data "She pats you on the butt.",45,"What a cheapskate.",-45
   Data "You won't be remembered.",10,"There isn't any change.",-10
   Data "You're tired of standing.",0,7
   Data "Sit at a table","Lean against the wall","Ask a waitress for a leg massage"
   Data "That was the last open table.",35,"The table you're at is reserved.",-35
   Data "Some girls lean next to you.",45,"Holding up walls loses you points.",-45
   Data "She'd rather massage it in private.",55,"She thinks you're weird.",-55
   Data "A waitress spills a drink on herself.",0,6
   Data "Shout "+Chr$(34)+"Good hands!"+Chr$(34),"Help her clean off","Yell "+Chr$(34)+"Look! That girl's wet!"+Chr$(34)
   Data "You got her attention.",45,"You'll never feel them.",-45
   Data "She doesn't know how to thank you.",60,"She's mad and doesn't want any help.",-60
   Data "Believe it or not, she is.",35,"Wrong again.",-35
   Data "It's pretty boring right now.",0,10
   Data "Yell "+Chr$(34)+"Ya feel it? I feel it!"+Chr$(34),"Shout "+Chr$(34)+"Yo! Sweetheart!"+Chr$(34),"Chant "+Chr$(34)+"Hard-on! Hard-on!"+Chr$(34)
   Data "They feel it.",25,"Nobody feels it and nobody cares.",-25
   Data "All the pretty girls turn around.",40,"Only the ugly girls look.",-40
   Data "Some of the girls say "+Chr$(34)+"Where?"+Chr$(34),35,"Yours is nothing to brag about.",-35
   Data "A guy is handing out bumper stickers.",0,1
   Data "Say "+Chr$(34)+"Wouldn't look right on my Rolls"+Chr$(34),"Take one and stick it on his back","Blow your nose in one"
   Data "It wouldn't, if you had one.",15,"Wouldn't look right on your junker.",-15
   Data "The crowd thinks it's hilarious.",55,"He sticks one on your face.",-55
   Data "Beats using your bare hands.",40,"It doesn't hold it too well.",-40
   Data "A strangely happy girl says "+Chr$(34)+"Hi!"+Chr$(34),1,8
   Data Chr$(34)+"Evidently"+Chr$(34),Chr$(34)+"Do I know you?"+Chr$(34),Chr$(34)+"Hey! How've you been?"+Chr$(34)
   Data "She laughs and says "+Chr$(34)+"I'm not high!"+Chr$(34),30,"She doesn't get the joke.",-30
   Data "She says "+Chr$(34)+"You can if you want to."+Chr$(34),50,"She says "+Chr$(34)+"I wasn't talking to you."+Chr$(34),-50
   Data "She says "+Chr$(34)+"I've been lonely."+Chr$(34),45,"She wasn't talking to you.",-45
   Data "A waitress asks if you want anything.",0,3
   Data "Say "+Chr$(34)+"I want you to bend over"+Chr$(34),"Nod your head yes and say "+Chr$(34)+"Nope"+Chr$(34),"Say "+Chr$(34)+"A date would be nice"+Chr$(34)
   Data "She says "+Chr$(34)+"Ok, maybe later."+Chr$(34),65,"She thinks you're a pervert.",-65
   Data "It got a laugh out of her.",35,"She says "+Chr$(34)+"Quit wasting my time!"+Chr$(34),-35
   Data "She says "+Chr$(34)+"I was going to ask you!"+Chr$(34),55,"Not for her it wouldn't.",-55
   Data "Go play a game of...",4,13
   Data "Foosball","Pinball","Pool"
   Data "Foosball impresses girls.",35,"You suck at foosball tonight.",-35
   Data "You set a record high score.",30,"So you like to play with balls?",-30
   Data "You make some incredible shots.",20,"You can't even shoot straight.",-20
   Data "Someone drops their drink.",0,6
   Data "Shout "+Chr$(34)+"Nice catch!"+Chr$(34),"Smile and laugh quietly","Yell "+Chr$(34)+"Ho! Fumble!"+Chr$(34)
   Data "My, aren't we sarcastic.",25,"No, it was a bad throw.",-25
   Data "It wasn't that funny anyway.",20,"You chickened out.",-20
   Data "Now kick the ice across the floor.",40,"A 300-lb. linebacker dropped it.",-55
   Data "A girl is waving at you.",0,8
   Data "Go talk to her","Smile at her","Wave back"
   Data "She says "+Chr$(34)+"Guess what I want to do?"+Chr$(34),50,"She just has cerebral palsy.",-50
   Data "You playboy, you.",45,"She gets a good look at you.",-45
   Data "Fine. Now go have sex with her.",55,"She wasn't waving at you.",-55
   Data "It's getting late.",1,1
   Data Chr$(34)+"Well, it's been real"+Chr$(34),Chr$(34)+"Yep, I guess it gelled"+Chr$(34),Chr$(34)+"Quite an evening, but not really"+Chr$(34)
   Data "Hell, it's been 5-dimensional.",30,"It never came close to reality.",-30
   Data "You're damn right it did.",40,"Don't kid yourself.",-40
   Data "It was, but not actually.",20,"What did you expect?",-20
   Data "You may be about to barf.",8,7
   Data "Do it on the bar","Spray it out your nose","Do it in an empty pitcher"
   Data "Nope, the barf never developed.",40,"What a runny mess.",-55
   Data "Nope, the barf never developed.",40,"It was a beautiful thing.",25
   Data "Nope, the barf never developed.",40,"Now you can drink it again.",40
   Data "A waitress says "+Chr$(34)+"Be careful going home."+Chr$(34),0,3
   Data "Say "+Chr$(34)+"Ok, where's your house?"+Chr$(34),"Say "+Chr$(34)+"You better walk me to my car"+Chr$(34),"Say "+Chr$(34)+"Of course, I always use rubbers!"+Chr$(34)
   Data "She says "+Chr$(34)+"Sure, stop by later on."+Chr$(34),45,"It's nowhere near yours.",-30
   Data "She does (you sly dog).",55,"She says "+Chr$(34)+"Take a hike!"+Chr$(34),-55
   Data "She'd let you use one on her.",50,"She calls you a dick.",-55
   Data "Some people are blocking the door.",0,9
   Data "Push your way through","Say "+Chr$(34)+"Excuuuuuse me"+Chr$(34),"Try to walk around them"
   Data "They don't want any trouble.",25,"Everyone thinks you're rude.",-25
   Data "They all get out of your way.",30,"There's no excuse for you.",-30
   Data "They're sorry for being in the way.",40,"One of them trips you.",-40
   Data "A guy spills some beer on your leg.",0,7
   Data "Stare at him angrily","Just let it go","Say "+Chr$(34)+"Hey, watch it!"+Chr$(34)
   Data "He's scared you'll hit him.",45,"He dumps some more on your foot.",-45
   Data "You've shown your maturity.",50,"You feel like a wimp.",-50
   Data "He gets down & wipes off your shoe.",35,"He's blind and asks "+Chr$(34)+"Watch what?"+Chr$(34),-35
   Data "A girl asks "+Chr$(34)+"What's new?"+Chr$(34),1,8
   Data Chr$(34)+"I've got a new waterbed"+Chr$(34),Chr$(34)+"Your nipples look quite hard"+Chr$(34),Chr$(34)+"I've got 7 if you've got 5"+Chr$(34)
   Data "Her pants are halfway down.",55,"She gets sea-sick easily.",-55
   Data "She says "+Chr$(34)+"You look hard yourself."+Chr$(34),65,"She thinks you're disgusting.",-65
   Data "She thinks it's more than 7.",70,"Tough luck, she's on the rag.",-70
   Data "You just farted.",0,13
   Data "Sneer and point at your friend","Stare at the ceiling","Stand upwind"
   Data "Everyone thinks it was him.",40,"Everyone knows it was you.",-40
   Data "Nobody noticed anyway.",25,"You look guilty as hell.",-25
   Data "The cloud drifts away from you.",30,"The wind direction shifts.",-30
   Data "A girl is trying to get by you.",0,3
   Data "Step back and let her by","Rub up against her as she goes by","Stand in her way on purpose"
   Data "She says "+Chr$(34)+"Thank you very much!"+Chr$(34),30,"She steps on your toes.",-30
   Data "You get a cheap thrill from it.",45,"She coughs in your face.",-45
   Data "She grabs your waist and moves you.",50,"She shoves you out of the way.",-50
   Data "Someone stole your coat.",0,1
   Data "Steal someone else's","Go home without it","Complain loudly"
   Data "Fair is fair.",45,"They catch you.",-45
   Data "There were lice in it anyway.",25,"You're a real sucker.",-25
   Data "A waitress finds it on the floor.",35,"Whining about it won't help.",-35
   Data "You're trying not to puke.",9,4
   Data "Put your hand on your stomach","Think about ice water","Close your eyes"
   Data "You lucked out and didn't puke.",40,"Your ulcer makes you throw up.",-55
   Data "You lucked out and didn't puke.",40,"Ice water with puke in it.",-25
   Data "You lucked out and didn't puke.",40,"It makes you dizzy and even sicker.",-40
   Data "A decent girl asks you to her car.",1,8
   Data Chr$(34)+"Does it have engine trouble?"+Chr$(34),Chr$(34)+"No, let's go to my car"+Chr$(34),Chr$(34)+"My this is so sudden!"+Chr$(34)
   Data "She'd let you check under her hood.",55,"Are you a jerk or what?",-55
   Data "She doesn't mind.",65,"The contraceptives are in her car.",-65
   Data "She hopes it won't be.",70,"She changes her mind.",-70
   Data "Subhuman","Nobody","Total Zero","Geek","Loser","Lightweight","Amateur","Lush","Boozer","Lounge Lizard","Brewmaster","Party Monster","Drinking Man","Nighthawk","Social Expert","Swinger","Sex God"
   Data "No drink, no bonus.","Fine. Be a lightweight!","What's the matter with you?"
   Data "Too bad, you needed a drink.","Buy a drink, or else!","Come to a bar and not drink?"
   Data "You're empty-handed again?","Why aren't you drinking?","You wussied out again!"
   Data "Got an ulcer or something?","Peer pressure is turning critical!","You've lost your credibility!"
   Data "Fuck you ","Shit ","Damn ","Hell ","Fuck ","Eat shit ","Damn it ","Go to hell ","Fuck off ","Bullshit "
   Data "asshole","dipshit","gaywad","jerkoff","bastard","dildo","fagbait","pisspot","dickhead","fucker"
End Proc
Procedure TITLEPAGE
   Shared A$
   Clear Key : A$="" : Auto View Off : Screen Show 0 : Screen 0 : Cls : MEDINTERFACE[24]
   JTR: Pen 1 : Paper 0 : Cls
   Locate 0,20 : Centre "Programming & Music by Roland Acton"
   Locate 0,23 : Centre "LMB to start, SPACE for music menu,"
   Locate 0,24 : Centre "or wait for instructions"
   FLIPSCREENS
   T=Timer+1000 : Palette 0,$FFF : View
   Repeat
      KEYPRESS=Mouse Click
      A$=Right$(A$,5)+Inkey$
   Until((KEYPRESS=1) or(Timer>T) or(Right$(A$,1)=" ") or(A$="advice"))
   If((KEYPRESS<>1) and(Right$(A$,1)<>" ") and(A$<>"advice"))
      Pen 1 : Paper 0 : Cls : Locate 0,4
      Centre "YOU ARE ON A PUB CRAWL!" : Print : Print : Pen 2
      Centre "This is a game of social skill," : Print
      Centre "drinking ability, and luck. Points are" : Print
      Centre "scored by making the best decisions in" : Print
      Centre "given situations. Making bad choices" : Print
      Centre "will usually result in fewer points." : Print
      Centre "Choose wisely!" : Print : Print
      Centre "You'll begin with only $10 and 100" : Print
      Centre "points of know-how. To make a choice," : Print
      Centre "just click on it with the LMB, and the" : Print
      Centre "game will tell you what happens." : Print : Print
      Centre "There are six bars, each with different" : Print
      Centre "events. Visit them all for maximum" : Print
      Centre "entertainment."
      FLIPSCREENS
      T=Timer+1000 : Palette 0,$FFF,$FF : View
      Repeat
         KEYPRESS=Mouse Click
         A$=Right$(A$,5)+Inkey$
      Until((KEYPRESS=1) or(Timer>T) or(Right$(A$,1)=" ") or(A$="advice"))
   End If
   If((KEYPRESS<>1) and(Right$(A$,1)<>" ") and(A$<>"advice"))
      Pen 1 : Paper 0 : Cls : Locate 0,4
      Centre "TECHNICAL NOTES" : Print : Print : Pen 2
      Centre "This game is an adaptation of the" : Print
      Centre "original "+Chr$(34)+"Drink & Drown"+Chr$(34)+", written on" : Print
      Centre "the Commodore 64." : Print : Print
      Centre "The Amiga version was programmed in" : Print
      Centre "AMOS BASIC and the music was composed" : Print
      Centre "with MED 3.10." : Print : Print
      Centre "The music "+Chr$(34)+"Delta 1991"+Chr$(34)+" is a" : Print
      Centre "rearrangement of the music composed by" : Print
      Centre "Rob Hubbard for the Commodore 64 game" : Print
      Centre Chr$(34)+"Delta"+Chr$(34)+" in 1986. All else is original." : Print : Print : Pen 3
      Centre "Keep on partying!"
      FLIPSCREENS
      T=Timer+1000 : Palette 0,$FFF,$F0F,$F0 : View
      Repeat
         KEYPRESS=Mouse Click
         A$=Right$(A$,5)+Inkey$
      Until((KEYPRESS=1) or(Timer>T) or(Right$(A$,1)=" ") or(A$="advice"))
   End If
   If((KEYPRESS<>1) and(Right$(A$,1)<>" ") and(A$<>"advice")) Then Goto JTR
   MEDINTERFACE[0]
End Proc
Procedure STATUSLINE
   Shared CASH#,SCORE
   Cls
   Paper 2
   Locate 0,8
   Print "                                        "
   Locate 0,8
   Print "Score:";SCORE
   Locate 20,8
   Print "Cash: $";
   If CASH#=>10.0
      Print Using "##.##";CASH#
   Else
      Print Using "#.##";CASH#
   End If
   Paper 0
End Proc
Procedure GIVEEVENT
   Shared SITUATION$(),EVENT
   Locate 20,3 : POSITION=1 : LEFT=19
   For C=1 To Len(SITUATION$(EVENT))
      If Mid$(SITUATION$(EVENT),C,1)=" " or C=Len(SITUATION$(EVENT))
         WORDCOUNT=(C+1)-POSITION
         If WORDCOUNT>LEFT
            Print : Locate 20, : LEFT=19
         End If
         Print Mid$(SITUATION$(EVENT),POSITION,WORDCOUNT); : LEFT=LEFT-WORDCOUNT : POSITION=C+1
      End If
   Next
End Proc
Procedure POLLRESPONSE
   Shared EVENT,RESPONSE,SPECIAL(),RESPONSE$()
   Locate 0,12
   If(SPECIAL(EVENT)=0) or(SPECIAL(EVENT)=>5)
      Print "Do you..."
   Else If SPECIAL(EVENT)=1
         Print "Do you say..."
      Else If(SPECIAL(EVENT)=>2) and(SPECIAL(EVENT)<=4)
            Print
         End If
      End If
   End If
   Print : For C=1 To 3 : Print RESPONSE$(EVENT,C) : Next
   FLIPSCREENS
   Reset Zone
   Set Zone 1,0,14*8 To 319,(15*8)-1
   Set Zone 2,0,15*8 To 319,(16*8)-1
   Set Zone 3,0,16*8 To 319,(17*8)-1
   CHECKER: Repeat
      KEYPRESS=Mouse Key
   Until KEYPRESS=1
   KEYPRESS=Mouse Zone
   If KEYPRESS<1 or KEYPRESS>3 Then Goto CHECKER
   RESPONSE=KEYPRESS
End Proc
Procedure DISPLAYPICTURE
   Ink 4 : Bar 0,0 To(20*8)-2,(8*8)-2
   Paper 4 : Locate 5,4 : Print "(picture)" : Paper 0
End Proc
Procedure MEDINTERFACE[TUNE]
   Shared MEDLOCATION,MEDMOD
   Call Leek(MEDLOCATION+4)
   If TUNE>0
      Doke Leek(MEDLOCATION+8),TUNE-1 : Areg(0)=MEDMOD : Call Leek(MEDLOCATION)
   End If
End Proc
Procedure TWIDDLEFINGERS
   Shared MEDLOCATION
   If Deek(Leek(MEDLOCATION+8)+2)>0
      Repeat
      Until Deek(Leek(MEDLOCATION+8)+2)=0
   Else
      WASTETIME
   End If
End Proc
Procedure RANKINGS
   Shared RANK$(),SCORE,PEAKSCORE
   Cls : Centre "YOUR RANK"
   Locate 0,4 : Pen 2
   For C=17 To 1 Step -1 : Print "   "+RANK$(C) : Next
   Pen 5 : Locate 22,11 : Print "Final Score:";SCORE
   Locate 22,13 : Print "Peak Score:";PEAKSCORE
   PLACE=(SCORE/100)+3
   If PLACE<1 Then PLACE=1
   If PLACE>17 Then PLACE=17
   Locate 0,21-PLACE : Pen 5 : Print "-->"; : Pen 4 : Print RANK$(PLACE); : Pen 5 : Print "<--" : Pen 1
   Flash 4,"(fff,30)(000,30)"
   MEDINTERFACE[45]
   FLIPSCREENS
   TWIDDLEFINGERS
   Flash Off
End Proc
Procedure BESTSCORE
   Shared SCORE,PEAKSCORE
   If SCORE>PEAKSCORE Then PEAKSCORE=SCORE
End Proc
Procedure FLIPSCREENS
Screen Swap 0
Wait Vbl
Screen Copy Physic To Logic
End Proc
Procedure WASTETIME
   For C=1 To 200 : Wait Vbl : Next
End Proc
Procedure ADVICE
   Pen 5 : Paper 2 : Cline : Centre "Roland's School of Cool"
   Locate 0,24 : Cline : Centre "Roland's School of Cool" : Pen 6 : Paper 0
   Locate 0,5 : Centre "MASTERING THE EVENTS" : Print : Print : Pen 7
   Centre "Let's say you're given this situation:" : Print : Print : Print : Print : Pen 1
   Print "Someone yells "+Chr$(34)+"The Martians are coming!"+Chr$(34)
   Print "Do you..." : Print
   Print "Stay where you are"
   Print "Go out and meet them"
   Print "Turn on the radio" : Print
   Pen 2 : Locate 0,22 : Centre "<Click LMB>"
   FLIPSCREENS
   Palette 0,$FFF,$F,$F0,$F00,$FF0,$F0F,$FF : View
   Repeat
   Until(Mouse Key=0)
   Repeat
   Until(Mouse Click=1)
   Cls : Pen 5 : Paper 2 : Cline : Centre "Roland's School of Cool"
   Locate 0,24 : Cline : Centre "Roland's School of Cool" : Pen 7 : Paper 0
   Locate 0,2 : Centre "For each response the computer has two" : Print
   Centre "comebacks, one good - and one BAD!" : Print : Print : Pen 1
   Print "Stay where you are"
   Print "    He meant martinis. "; : Pen 3 : Print "+40" : Pen 1
   Print "    You look scared. "; : Pen 4 : Print "-35" : Print : Pen 1
   Print "Go out and meet them"
   Print "    You've saved the earth. "; : Pen 3 : Print "+30" : Pen 1
   Print "    Actually, it's the cops. "; : Pen 4 : Print "-50" : Print : Pen 1
   Print "Turn on the radio"
   Print "    Your favorite station is on. "; : Pen 3 : Print "+25" : Pen 1
   Print "    Gotcha! "; : Pen 4 : Print "-25" : Pen 7 : Print
   Centre "Whether your choice turns out good or" : Print
   Centre "bad is random - but notice that the" : Print
   Centre "same number of points isn't always" : Print
   Centre "at risk!" : Print : Print
   Pen 2 : Locate 0,22 : Centre "<Click LMB>"
   FLIPSCREENS
   View
   Repeat
   Until(Mouse Key=0)
   Repeat
   Until(Mouse Click=1)
   Cls : Pen 5 : Paper 2 : Cline : Centre "Roland's School of Cool"
   Locate 0,24 : Cline : Centre "Roland's School of Cool" : Pen 6 : Paper 0
   Locate 0,3 : Centre "DRINKING" : Print : Print : Pen 7
   Centre "Choose different drinks to find the" : Print
   Centre "SECRET SPECIAL. Beware of puking too" : Print
   Centre "much - pass out and the game's over." : Print
   Centre "Turning down drinks will help - for a" : Print
   Centre "while - but costs you points." : Print : Print : Print : Pen 6
   Centre "SWEARING" : Print : Print : Pen 7
   Centre "Try to say the SUPER SWEAR for a bonus." : Print
   Centre "Remember, though, that each mis-swear" : Print
   Centre "loses you 10 points." : Print : Print : Print : Pen 6
   Centre "GOOD LUCK!" : Print : Print
   Pen 2 : Locate 0,22 : Centre "<Click LMB>"
   FLIPSCREENS
   View
   Repeat
   Until(Mouse Key=0)
   Repeat
   Until(Mouse Click=1)
End Proc
Procedure MUSMENU
   Pen 4 : Paper 0
   Cls : Paper 3 : Cline : Centre "MUSIC MENU" : Locate 0,2 : Pen 2 : Paper 0 : Reset Zone : Restore MUSDAT
   For C=1 To 19
      Locate 10, : Read B$,NUM : A$=Zone$(B$,NUM) : Print A$
   Next
   Locate 0,22 : Pen 1 : Paper 3 : Centre "      " : Print : Centre " EXIT " : Print : Centre "      "
   Set Zone 20,17*8,22*8 To(23*8)-1,(25*8)-1
   FLIPSCREENS
   Palette 0,$FFF,$F0,$F,$FF0 : View : Show
   MQ: Repeat
      KEYPRESS=Mouse Key
   Until(KEYPRESS=0)
   MM: Repeat
      KEYPRESS=Mouse Click
   Until KEYPRESS=1
   KEYPRESS=Mouse Zone
   If KEYPRESS<1 or KEYPRESS>51
      Goto MM
   End If
   If(KEYPRESS<>20) Then MEDINTERFACE[KEYPRESS] : Goto MQ
   MEDINTERFACE[0] : Hide
   MUSDAT: Data "One For The Road",24,"Decisions, Decisions",50
   Data "Sleazy Bar Blues",1,"Hairy-Kiri",2,"Working Girl",3
   Data "Dirty Dancing",4,"Money Money Money",5,"Skips & Trips",6
   Data "Peer Pressure",7,"Ice Attack",8,"Flamin' Mad",9
   Data "Eventlessness",10,"Delta 1991",11,"The Game Master",13
   Data "The Winner",17,"The Loser",18
   Data "What A Guy",14,"Night's End",45,"Free Software Rulez",51
End Proc
Procedure CREDITS
   Load Iff "Credits",0
   FLIPSCREENS
   Screen Show 0 : View
   MEDINTERFACE[51]
   TWIDDLEFINGERS
End Proc